원원이의 블로그

Speaker 만들기 4편 (SD카드에있는 WAV파일을 OLED에 표시하고 재생)

원원 — Tue, 10 Feb 2026 23:57:05 +0900

안녕하세요. 오늘은 SD카드에있는 SD카드에있는 WAV파일을 OLED에 표시하고 재생해보겠습니다.

3편에서 만들었던 회로도에서 OLED와 버튼1개를 추가했습니다.

OLED는 SSD1306을 이용해서 I2C 통신을하는 2.42인치 제품이고 해상도는 128x64입니다.
SSD1306을 사용하므로 라이브러리가 많이 있습니다.

코드를 만드는 과정입니다.
1. OLED에 글자 표시
2. 버튼 클릭하면 화살표 이동
3. SD카드에서 WAV파일 읽어서 화면표시하고 클릭하면 WAV파일재생

1. OLED에 글자 표시

#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>

/* SD CARD */
#define SD_SCK 18
#define SD_MISO 19
#define SD_MOSI 23
#define SD_CS 5

/* BUTTON */
#define BTN1 16
#define BTN2 17
#define BTN3 21

/* OLED */
#define OLED_SDA 27
#define OLED_SCL 14
#define OLED_ADDR 0x3C
#define SCREEN_WIDTH 128
#define SCREEN_HEIGHT 64

Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, -1);

void setup()
{
  // UART SETTING
  Serial.begin(115200);

  // BUTTON INIT
  pinMode(BTN1, INPUT_PULLUP);
  pinMode(BTN2, INPUT_PULLUP);
  pinMode(BTN3, INPUT_PULLUP);

  // OLED INIT
  Wire.begin(OLED_SDA, OLED_SCL);
  if (!display.begin(SSD1306_SWITCHCAPVCC, OLED_ADDR)) {
    Serial.println("SSD1306 init failed!");
    while (1) { delay(10); }
  }

  // OLED DISPLAY
  display.clearDisplay();
  display.setTextColor(SSD1306_WHITE);
  
  display.setTextSize(1);
  display.setCursor(0, 0);
  display.println("HELLO");

  display.setTextSize(2);
  display.setCursor(0, 0+8);
  display.println("WORLD");

  display.setTextSize(3);
  display.setCursor(0, 0+8+16);
  display.println("WOWON");
  display.display();
}

void loop()
{
  
}

Adafruit SSD1306 라이브러리를 이용합니다.
글자의 크기를 정하는 함수는 display.setTextsize()입니다. 크기가 1이면 y축의 크기가 8정도 먹습니다. 그래서 크기를 1로 사용하면 8*8=64니까 8줄정도 이용 가능합니다. 글자의크기가 2면 y축의 크기는 16정도 먹습니다.
MCU가 OLED와 I2C 통신을 수행하는 시점은 display.display() 호출 시입니다. 그 전까지는 MCU 내부 프레임버퍼에 화면 데이터를 저장합니다.

2. 버튼 클릭하면 화살표 이동

#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>

/* BUTTON */
#define BTN1 16
#define BTN2 17
#define BTN3 21

/* OLED */
#define OLED_SDA 27
#define OLED_SCL 14
#define OLED_ADDR 0x3C
#define SCREEN_WIDTH 128
#define SCREEN_HEIGHT 64

int8_t oledLine = 0; // MAX : 8
uint8_t arrayBtn[3] = {BTN1,BTN2,BTN3};
Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, -1);


void oled_display(uint8_t btn)
{
  display.clearDisplay();
  display.setTextSize(1);
  display.setTextColor(SSD1306_WHITE);

  if(btn == BTN1)
  {
    oledLine++;
  }
  else
  {
    oledLine --;
  }

  if(oledLine < 0)
  {
    oledLine = 0;
  }
  if(oledLine > 7)
  {
    oledLine = 7;
  }

  display.setCursor(0, oledLine*8);
  display.println(">");
  display.display();

  Serial.print("CURRENT LINE : ");
  Serial.println(oledLine);
}

void setup()
{
  // UART SETTING
  Serial.begin(115200);

  // BUTTON INIT
  pinMode(BTN1, INPUT_PULLUP);
  pinMode(BTN2, INPUT_PULLUP);
  pinMode(BTN3, INPUT_PULLUP);

  // OLED INIT
  Wire.begin(OLED_SDA, OLED_SCL);
  if (!display.begin(SSD1306_SWITCHCAPVCC, OLED_ADDR)) {
    Serial.println("SSD1306 init failed!");
    while (1) { delay(10); }
  }

  // INIT OLED DISPLAY
  display.clearDisplay();
  display.setTextSize(1);
  display.setTextColor(SSD1306_WHITE);
  display.setCursor(0, 0);
  display.println(">");
  display.display();
}

bool edgeFalling(bool cur, bool &prev)
{
  bool hit = (prev == HIGH && cur == LOW);
  prev = cur;
  return hit;
}
bool check_btn[3];
bool buffer_btn[3] = {true, true, true};

void loop()
{
  uint8_t c;
  for(c=0; c<3; c++)
  {
    check_btn[c] = digitalRead(arrayBtn[c]);
    
    if(edgeFalling(check_btn[c],buffer_btn[c]))
    {
      Serial.print("CLICK BTN : ");
      Serial.println(c);
      //BTN1: UP , BTN2 : DOWN
      if(arrayBtn[c] == BTN1 || arrayBtn[c] == BTN2)
      {
        oled_display(arrayBtn[c]);
      }
    }
  }
}

버튼이 3개 있는데 버튼을 클릭하면 화살표 (>)를 화면에서 이동하게 됩니다.
여기서 중요한건 "버튼을 클릭할때"를 감지해야 합니다. 인터럽트를 이용할수도 있었지만 인터럽트를 이용하지않았습니다. 클릭하지않았을때 버튼의 상태는 HIGH이고 버튼을 클릭하면 LOW가 됩니다.(falling edge)
falling edge를 구별해주는 함수가 edgeFalling입니다. check_btn은 버튼의 현재상태가 들어가게 되고 buffer_btn은 이전에 읽은 버튼의 상태가 들어가게 됩니다. 그래서 현재 버튼의 상태가 LOW이고 이전 버튼의 상태가 HIGH이면 버튼이 클릭된 상태로 인식합니다.
버튼이 클릭됐으면 oled_display 함수를 호출해서 oledLine을 이동시키고 화면에 >를 표시합니다. 글자크기가 1이므로 y축은 8씩 이동시키게 됩니다.

3. SD카드에서 WAV파일 읽어서 화면표시하고 클릭하면 WAV파일재생

#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>
#include <SD.h>
#include <SPI.h>
#include <ESP_I2S.h>

#define BTN1 16
#define BTN2 17
#define BTN3 21

#define OLED_SDA 27
#define OLED_SCL 14
#define OLED_ADDR 0x3C
#define SCREEN_WIDTH 128
#define SCREEN_HEIGHT 64

#define SD_SCK  18
#define SD_MISO 19
#define SD_MOSI 23
#define SD_CS   5

#define BCLK 26
#define LRC  25
#define DIN  22

#define MAX_WAV_FILES 80
#define OLED_LINES 8

Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, -1);
I2SClass i2s;
File f;

uint8_t arrayBtn[3] = {BTN1, BTN2, BTN3};
bool check_btn[3];
bool buffer_btn[3] = {true, true, true};

String wavList[MAX_WAV_FILES];
int16_t wavCount = 0, wav_top = 0, wav_idx = 0;
int8_t oledLine = 0;

bool playing = false;
bool cancel_req = false;

typedef struct {
  uint16_t audioFormat;
  uint16_t numChannels;
  uint32_t sampleRate;
  uint16_t bitsPerSample;
  uint32_t dataOffset;
  uint32_t dataSize;
  uint32_t bytesPerSec;
  uint32_t totalMs;
} wav_info_t;

wav_info_t curWav = {};

bool edgeFalling(bool cur, bool &prev){ bool hit=(cur==LOW && prev==HIGH); prev=cur; return hit; }
bool isWavFile(const String &name){ String s=name; s.toLowerCase(); return s.endsWith(".wav"); }
String fitOled(const String &s){ const int n=18; if((int)s.length()<=n) return s; return s.substring(0,n-3)+"..."; }

void sd_scan_wav(){
  wavCount=0;
  File root=SD.open("/");
  if(!root || !root.isDirectory()) return;
  while(true){
    File e=root.openNextFile();
    if(!e) break;
    if(!e.isDirectory()){
      String n=String(e.name());
      if(isWavFile(n) && wavCount<MAX_WAV_FILES) wavList[wavCount++]=n;
    }
    e.close();
  }
  root.close();
  wav_top=0; wav_idx=0; oledLine=0;
}

void oled_draw_list(){
  display.clearDisplay();
  display.setTextSize(1);
  display.setTextColor(SSD1306_WHITE);
  if(wavCount<=0){
    display.setCursor(0,0); display.println("No .wav in /"); display.display(); return;
  }
  for(int i=0;i<OLED_LINES;i++){
    int idx=wav_top+i; if(idx>=wavCount) break;
    display.setCursor(0,i*8); display.print((i==oledLine)?">":" ");
    display.setCursor(8,i*8); display.println(fitOled(wavList[idx]));
  }
  display.display();
}

void oled_move(uint8_t btn){
  if(wavCount<=0 || playing) return;
  if(btn==BTN1){ if(wav_idx<wavCount-1) wav_idx++; }
  else if(btn==BTN2){ if(wav_idx>0) wav_idx--; }
  if(wav_idx<wav_top) wav_top=wav_idx;
  if(wav_idx>=wav_top+OLED_LINES) wav_top=wav_idx-(OLED_LINES-1);
  oledLine=(int8_t)(wav_idx-wav_top);
  oled_draw_list();
}

i2s_data_bit_width_t bitWidthFrom(uint16_t bps){
  switch(bps){
    case 16: return I2S_DATA_BIT_WIDTH_16BIT;
    case 24: return I2S_DATA_BIT_WIDTH_24BIT;
    case 32: return I2S_DATA_BIT_WIDTH_32BIT;
    default: return I2S_DATA_BIT_WIDTH_16BIT;
  }
}

bool wav_open_selected(){
  if(wavCount<=0) return false;

  String path="/"+wavList[wav_idx];
  if(f) f.close();
  f = SD.open(path.c_str(), FILE_READ);
  if(!f) return false;

  uint8_t header[44];
  if(f.read(header,44)!=44){ f.close(); return false; }

  curWav.audioFormat   = header[20] | (header[21]<<8);
  curWav.numChannels   = header[22] | (header[23]<<8);
  curWav.sampleRate    = (uint32_t)header[24] | ((uint32_t)header[25]<<8) | ((uint32_t)header[26]<<16) | ((uint32_t)header[27]<<24);
  curWav.bitsPerSample = header[34] | (header[35]<<8);

  uint32_t dataSize = (uint32_t)header[40] | ((uint32_t)header[41]<<8) | ((uint32_t)header[42]<<16) | ((uint32_t)header[43]<<24);

  curWav.dataOffset = 44;
  curWav.dataSize   = dataSize;
  curWav.bytesPerSec = curWav.sampleRate * curWav.numChannels * (curWav.bitsPerSample/8);
  curWav.totalMs = (curWav.bytesPerSec==0)?0:(uint32_t)((uint64_t)curWav.dataSize*1000ULL/curWav.bytesPerSec);

  if(curWav.audioFormat!=1) { f.close(); return false; }
  if(!(curWav.numChannels==1 || curWav.numChannels==2)) { f.close(); return false; }
  if(!(curWav.bitsPerSample==16 || curWav.bitsPerSample==24 || curWav.bitsPerSample==32)) { f.close(); return false; }

  i2s.setPins(BCLK, LRC, DIN);
  if(!i2s.begin(I2S_MODE_STD, curWav.sampleRate, bitWidthFrom(curWav.bitsPerSample),
                (curWav.numChannels==1)?I2S_SLOT_MODE_MONO:I2S_SLOT_MODE_STEREO)){
    f.close(); return false;
  }

  f.seek(curWav.dataOffset);
  return true;
}

void draw_play_ui(uint32_t rem_ms, uint32_t done_bytes){
  display.clearDisplay();
  display.setTextSize(1);
  display.setTextColor(SSD1306_WHITE);

  display.setCursor(0,0);
  display.print("PLAY ");
  display.println(fitOled(wavList[wav_idx]));

  uint32_t s = rem_ms/1000, m=s/60; s%=60;
  display.setCursor(0,16);
  display.print("Remain ");
  if(m<10) display.print("0"); display.print(m);
  display.print(":");
  if(s<10) display.print("0"); display.print(s);

  int x=0,y=32,w=128,h=10;
  display.drawRect(x,y,w,h,SSD1306_WHITE);
  int fill = (curWav.dataSize==0)?0:(int)((uint64_t)done_bytes*(w-2)/curWav.dataSize);
  if(fill<0) fill=0; if(fill>w-2) fill=w-2;
  display.fillRect(x+1,y+1,fill,h-2,SSD1306_WHITE);

  display.setCursor(0,48);
  display.println("BTN3: Cancel");

  display.display();
}

void stop_play(){
  cancel_req=false;
  playing=false;
  if(f) f.close();
  i2s.end();
  oled_draw_list();
}

void start_play(){
  cancel_req=false;
  if(!wav_open_selected()){ oled_draw_list(); return; }
  playing=true;

  static uint8_t buf[4096];
  uint32_t done=0, last_ui=0;
  bool prev3=true;

  uint32_t ignore_cancel_until = millis() + 250;

  while(playing && f.available()){
    bool cur3 = digitalRead(BTN3);
    if(millis() > ignore_cancel_until) {
      if(edgeFalling(cur3, prev3)) cancel_req=true;
    } else {
      prev3 = cur3;
    }
    if(cancel_req) break;

    int len = f.read(buf, sizeof(buf));
    if(len>0) i2s.write(buf, len);
    done += (len>0)?(uint32_t)len:0;

    uint32_t now=millis();
    if(now-last_ui>=120){
      last_ui=now;
      uint32_t rem_bytes = (done>=curWav.dataSize)?0:(curWav.dataSize-done);
      uint32_t rem_ms = (curWav.bytesPerSec==0)?0:(uint32_t)((uint64_t)rem_bytes*1000ULL/curWav.bytesPerSec);
      draw_play_ui(rem_ms, done);
    }
  }

  stop_play();
}

void setup(){
  Serial.begin(115200);

  pinMode(BTN1,INPUT_PULLUP);
  pinMode(BTN2,INPUT_PULLUP);
  pinMode(BTN3,INPUT_PULLUP);

  Wire.begin(OLED_SDA, OLED_SCL);
  if(!display.begin(SSD1306_SWITCHCAPVCC, OLED_ADDR)) while(1) delay(10);

  SPI.begin(SD_SCK, SD_MISO, SD_MOSI, SD_CS);
  if(!SD.begin(SD_CS, SPI)) while(1) delay(10);

  sd_scan_wav();
  oled_draw_list();
}

void loop(){
  for(uint8_t c=0;c<3;c++){
    check_btn[c]=digitalRead(arrayBtn[c]);
    if(edgeFalling(check_btn[c],buffer_btn[c])){
      if(arrayBtn[c]==BTN1 || arrayBtn[c]==BTN2) oled_move(arrayBtn[c]);
      if(arrayBtn[c]==BTN3){
        if(!playing) start_play();
      }
      delay(30);
    }
  }
}

BTN3을 클릭하면 wav파일이 재생되고 남은시간이 표시되게됩니다.

Speaker 만들기 3편 (회로도작성, SD카드에있는 WAV파일 버튼으로 재생)

원원 — Sun, 4 Jan 2026 22:02:14 +0900

안녕하세요. 오늘은 회로도를 작성해보고 SD카드에있는 WAV파일을 버튼으로 재생해보겠습니다.

2편에서 사용했던 회로에서 버튼2개만 추가하였습니다.

회로도에는 SD카드소켓기준으로 작성하였는데, 실제로는 SD카드 모듈을 이용했습니다. 핀 연결 구성에는 차이가 없습니다.
원래는 브레드보드에 연결하여 테스트를 진행하려고 했으나, 스피커 출력에서 잡음이 많이 발생하여 만능기판으로 변경하였습니다.
GPT 의견에 따르면, 브레드보드는 접촉 구조와 배선 특성으로 인해 노이즈에 취약합니다.

버튼위의 남은공간은 OLED를 추가해서 SD카드에있는 WAV파일을 보여주고 버튼을 이용해서 클릭한 WAV파일을 재생하는 형식으로 할 예정입니다. 현재 글 에서는 버튼1개당 wav파일 1개가 매칭되어있어서 버튼을 클릭하면 정해둔 wav파일이 재생합니다.

동작은 버튼의 상태를 읽어, 버튼이 클릭되면 WAV 파일을 재생하는 방식입니다.
WAV 파일 재생 중에는 파일이 끝날 때까지 다른 동작을 수행할 수 없습니다.
playWavOnce() 함수에서는 SD.open()이 실패할 경우 SD 카드를 다시 초기화하도록 구현하였습니다.
이는 전원이 인가된 상태에서 SD 카드를 제거한 후 다시 삽입하는 경우, SD.begin()을 다시 호출해야 하기 때문입니다.
SD 카드는 초기 삽입 시 Idle 상태이며, SD.begin()을 수행하면 Transfer 상태로 전환됩니다.
따라서 SD 카드를 제거 후 재삽입하면 다시 Idle 상태가 되므로, 정상적인 읽기 동작을 위해 SD.begin()을 재호출합니다.

소스코드(COMMIT : Initial commit)
https://github.com/yhunterr/speaker_esp32

BLE ESP32 Bluedroid_Beacon 코드 분석하기 2편-코드흐름

원원 — Tue, 25 Nov 2025 00:34:32 +0900

안녕하세요. 오늘은 1편에 이어서 ESP32 Bluedroid_Beacon 예제코드를 분석해보겠습니다.
1편에서는 프로젝트에서 사용한 전역변수 3개에대해 알아봤습니다.
2편에서는 프로젝트 main문의 흐름에대해 알아보겠습니다.

Bluetooth stack에는 Host랑 controller가 있습니다.
(1) Controller는 하드웨어+저수준 펌웨어가 동작하는 영역입니다. 실제 전파를 주고받는 부분이고 Physical Layer(실제 BLE radio 신호), Link Layer(광고, 연결관리, timing, encryption)가 여기에 속합니다.
(2) Host는 소프트웨어 스택입니다. GAP(연결/페어링/역할관리) , GATT(서비스, characteristic 읽기/쓰기) , ATT(실제 읽기/쓰기 요청 수행), L2CAP (패킷 분할/재조립+multiplexing), SMP(Pairing,Bonding, key교환)가 여기에 속합니다.
(3) HCI(Host Controller Interface)는 Host와 Controller가 데이터를 주고받는 표준 인터페이스입니다.

ESP32의 Bluetooth host에는 Bluedroid랑 Nimble이 있습니다.
Bluedroid는 Classic Bluetooth와 BLE가 가능합니다. Nimble은 BLE만 가능합니다. 그래서 Nimble은 Bluedroid대비 코드용량이 40~60% 더 적습니다.
이 글에서 사용하는 프로젝트는 Bluedroid 프로젝트입니다.

https://docs.espressif.com/projects/esp-idf/en/stable/esp32/api-guides/ble/overview.html

위에서 두가지를 말한 이유가 있습니다. app_main의 흐름은 다음과 같습니다.
1. NVS(Non-volatile Storage) 초기화 : ESP32안에 있는 플래시메모리 초기화
2. bt controller 초기화 : controller영역 초기화
3. bluedroid 초기화 : host영역 초기화
4. GAP 콜백등록 : GAP관련 이벤트 처리 준비
5. 광고데이터/SCAN데이터 시스템에 세팅
6. 광고시작

여기서 중요한게 4~5번입니다.
코드에서 adv_config_done에 ADV_CONFIG_FLAG랑 SCAN_RSP_CONFIG_FLAG를 줍니다.
그 이유는 esp_gap_cb에서 ADV DATA랑 SCAN DATA를 SET하고나서 광고를 시작하기 위함입니다.

esp_ble_gap_config_adv_data_raw는 광고데이터를 설정하는 API라서 스택이 설정작업을 끝내면 ESP_GAP_BLE_ADV_DATA_RAW_SET_COMPLETE_EVT 이벤트를 esp_gap_cb로 전달합니다.
그럼 아래 로그메세지 (503) BLE_BEACON: Advertising data raw set. status 0가 나옵니다.

esp_ble_gap_get_local_used_addr는 local address를 얻어외서 local_addr 변수에 값을 넣습니다.
그리고나서 scan_rsp_raw_data배열의 2~7번에 주소를 넣습니다. 이전에 해당배열을 선언할때 2~7번은 0x00으로 초기화했었습니다. {0x08, ESP_BLE_AD_TYPE_LE_DEV_ADDR, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, ...}

그렇게되면 scan data로 위의 그림과같이 주소가 나오게 됩니다.

esp_ble_gap_config_scan_rsp_data_raw는 마찬가지로 작업이끝나면 ESP_GAP_BLE_SCAN_RSP_DATA_RAW_SET_COMPLETE_EVT이벤트를 esp_gap_cb로 전달하고 I (503) BLE_BEACON: Scan response data raw set, status 0 로그가 나오게됩니다.
해당함수에서 이제 adv_config_done가 0이므로 esp_ble_gap_start_advertising를 하게되고ESP_GAP_BLE_ADV_START_COMPLETE_EVT 이벤트를 호출합니다. 그럼 로그(I (513) BLE_BEACON: Advertising start successfully)가 나오고 광고가 시작됩니다.

adv_config_done |= ADV_CONFIG_FLAG;

adv_config_done |= SCAN_RSP_CONFIG_FLAG;

ret = esp_ble_gap_config_adv_data_raw(adv_raw_data, sizeof(adv_raw_data));

if (ret) {

ESP_LOGE(DEMO_TAG, "config adv data failed, error code = %x", ret);

return;

}

ret = esp_ble_gap_get_local_used_addr(local_addr, &local_addr_type);

if (ret) {

ESP_LOGE(DEMO_TAG, "get local used address failed, error code = %x", ret);

return;

}

scan_rsp_raw_data[2] = local_addr[5];

scan_rsp_raw_data[3] = local_addr[4];

scan_rsp_raw_data[4] = local_addr[3];

scan_rsp_raw_data[5] = local_addr[2];

scan_rsp_raw_data[6] = local_addr[1];

scan_rsp_raw_data[7] = local_addr[0];

ret = esp_ble_gap_config_scan_rsp_data_raw(scan_rsp_raw_data, sizeof(scan_rsp_raw_data));

if (ret) {

ESP_LOGE(DEMO_TAG, "config scan rsp data failed, error code = %x", ret);

}

static void esp_gap_cb(esp_gap_ble_cb_event_t event, esp_ble_gap_cb_param_t *param)

{

switch (event) {

case ESP_GAP_BLE_ADV_DATA_SET_COMPLETE_EVT:

ESP_LOGI(DEMO_TAG, "Advertising data set, status %d", param->adv_data_cmpl.status);

adv_config_done &= (~ADV_CONFIG_FLAG);

if (adv_config_done == 0) {

esp_ble_gap_start_advertising(&adv_params);

}

break;

case ESP_GAP_BLE_ADV_DATA_RAW_SET_COMPLETE_EVT:

ESP_LOGI(DEMO_TAG, "Advertising data raw set, status %d", param->adv_data_raw_cmpl.status);

adv_config_done &= (~ADV_CONFIG_FLAG);

if (adv_config_done == 0) {

esp_ble_gap_start_advertising(&adv_params);

}

break;

case ESP_GAP_BLE_SCAN_RSP_DATA_SET_COMPLETE_EVT:

ESP_LOGI(DEMO_TAG, "Scan response data set, status %d", param->scan_rsp_data_cmpl.status);

adv_config_done &= (~SCAN_RSP_CONFIG_FLAG);

if (adv_config_done == 0) {

esp_ble_gap_start_advertising(&adv_params);

}

break;

case ESP_GAP_BLE_SCAN_RSP_DATA_RAW_SET_COMPLETE_EVT:

ESP_LOGI(DEMO_TAG, "Scan response data raw set, status %d", param->scan_rsp_data_raw_cmpl.status);

adv_config_done &= (~SCAN_RSP_CONFIG_FLAG);

if (adv_config_done == 0) {

esp_ble_gap_start_advertising(&adv_params);

}

break;

case ESP_GAP_BLE_ADV_START_COMPLETE_EVT:

if (param->adv_start_cmpl.status != ESP_BT_STATUS_SUCCESS) {

ESP_LOGE(DEMO_TAG, "Advertising start failed, status %d", param->adv_start_cmpl.status);

break;

}

ESP_LOGI(DEMO_TAG, "Advertising start successfully");

break;

default:

break;

}

로그

BLE ESP32 Bluedroid_Beacon 코드 분석하기 1편-전역변수

원원 — Sat, 22 Nov 2025 20:26:06 +0900

안녕하세요. 오늘은 ESP32 Bluedroid_Beacon 예제코드를 분석해보겠습니다.
사용하는 소스코드는 아래의 링크입니다.
https://github.com/espressif/esp-idf/tree/master/examples/bluetooth/ble_get_started/bluedroid/Bluedroid_Beacon

1편에서는 프로젝트에서 사용한 전역변수 3개를 알아보겠습니다.

* adv_params 구조체
- 광고를 어떻게 보낼지 설정하는 구조체입니다.

static esp_ble_adv_params_t adv_params = {

.adv_int_min = 0x20,

.adv_int_max = 0x20,

.adv_type = ADV_TYPE_SCAN_IND,

.own_addr_type = BLE_ADDR_TYPE_PUBLIC,

.channel_map = ADV_CHNL_ALL,

.adv_filter_policy = ADV_FILTER_ALLOW_SCAN_ANY_CON_ANY,

};

해당 구조체의 원형은 esp_gap_ble_api.h에 있습니다.

typedef struct {

uint16_t adv_int_min; /*!< Minimum advertising interval for

undirected and low duty cycle directed advertising.

Range: 0x0020 to 0x4000 Default: N = 0x0800 (1.28 second)

Time = N * 0.625 msec Time Range: 20 ms to 10.24 sec */

uint16_t adv_int_max; /*!< Maximum advertising interval for

undirected and low duty cycle directed advertising.

Range: 0x0020 to 0x4000 Default: N = 0x0800 (1.28 second)

Time = N * 0.625 msec Time Range: 20 ms to 10.24 sec Advertising max interval */

esp_ble_adv_type_t adv_type; /*!< Advertising type */

esp_ble_addr_type_t own_addr_type; /*!< Owner bluetooth device address type */

esp_bd_addr_t peer_addr; /*!< Peer device bluetooth device address */

esp_ble_addr_type_t peer_addr_type; /*!< Peer device bluetooth device address type, only support public address type and random address type */

esp_ble_adv_channel_t channel_map; /*!< Advertising channel map */

esp_ble_adv_filter_t adv_filter_policy; /*!< Advertising filter policy */

} esp_ble_adv_params_t;

해당 구조체의 선언은 모두 bluetooth 문서에 나와있습니다. (1252 page)

첫번째 변수부터 알아보겠습니다.
(1) adv_int_min, adv_int_max : 최소/최대 광고시간 간격 설정입니다. 범위는 20ms~10.24s 입니다.
코드에서는 min/max가 0x20이므로 32*0.625 = 20ms마다 광고하게 되어있습니다.

실제로 광고 간격을 측정해 보면 정확히 20ms로 반복되지 않고, 약 20~30ms 범위에서 랜덤하게 변화하는 것을 확인할 수 있습니다. 이 현상은 BLE 스펙에 의해 정의된 동작으로, 광고 간격(advertising interval)에 추가로 0~10ms의 랜덤 지연이 더해지기 때문입니다. 랜덤 딜레이가 필요한 이유는, BLE 광고가 단일 채널이 아닌 37, 38, 39 총 3개의 채널에서 반복적으로 브로드캐스트되기 때문입니다. 만약 여러 BLE 장치가 동일한 고정 간격(예: 20ms)으로 광고를 전송한다면, 각 장치가 동일한 타이밍에 3개의 채널에서 동시에 송신하게 되어 지속적인 패킷 충돌이 발생할 수 있습니다. 이를 방지하기 위해 BLE는 각 광고 이벤트마다 0~10ms의 랜덤 지연을 적용하여 충돌 패턴이 반복되지 않도록 하고, 결과적으로 광고 수신 성공률을 높입니다.

테스트로 min/max를 1초로 바꾸고 측정을 해보면 약 1초간격으로 광고가 찍힙니다.
min을 0.5초, max를 1초로 바꾸고 측정해봐도 약 1초간격으로 광고가 찍혔습니다.

(2) adv_typ : BLE 장치가 어떤 방식으로 광고할지 정의하는 속성입니다.
광고 타입은 총 5개가 있습니다. 데이터시트에나와있는게 소스코드에도 정의되어있습니다.

typedef enum {

ADV_TYPE_IND = 0x00,

ADV_TYPE_DIRECT_IND_HIGH = 0x01,

ADV_TYPE_SCAN_IND = 0x02,

ADV_TYPE_NONCONN_IND = 0x03,

ADV_TYPE_DIRECT_IND_LOW = 0x04,

} esp_ble_adv_type_t;

타입을 나누는 기준은 두가지입니다. 실제로 어떤기준인지 알아보겠습니다.
(1) 연결 가능?
아래 그림을보면 왼쪽은 CONNECT버튼이 없고 오른쪽은 CONNECT 버튼이 있습니다. 이게 연결가능? 속성입니다.
연결이 필요없는경우는 일반적으로 데이터 교환이 필요없는 Beacon같은경우입니다. 연결이 필요한경우는 데이터교환이 필요한 온도계같은 경우입니다.

(2) 스캔요청에 응답가능?
스캔요청은 scanner가 device에게 scan을 요청하는 기능입니다.
사용하는 이유는 크게 3가지입니다.
[1] Advertising data의 크기가 제한되어있기 때문입니다. Advertising data의 크기는 31바이트이고 Scan Response Data의 크기는 31바이트입니다.
[2] Scanner가 원할때만 추가 데이터를 제공해서 전력과 채널 사용 효율을 높이기 위함입니다.
[3] 연결전에 device 기능/정체성 확인이 필요하기때문입니다. Scan response에 Profile UUID나 Device Type같은걸 넣으면 탐색이 쉽습니다.

정리하면 아래의 표와 같습니다.

No	TYPE	conntable	scannable
0	ADV_TYPE_IND	O	O
1	ADV_TYPE_DIRECT_IND_HIGH	O	X
2	ADV_TYPE_SCAN_IND	X	O
3	ADV_TYPE_NONCONN_IND	X	X
4	ADV_TYPE_DIRECT_IND_LOW	O	X

1,4번은 옵션이 같은데 HIGH/LOW라고 적혀있습니다.
Direct Advertising이란 특정 장치만 연결을 허용하는 기능입니다.
예를 들어 무선 이어폰이 마지막으로 연결된 스마트폰을 다시 찾을 때나, 스마트워치가 사용자의 스마트폰 근처에 있는지 확인할 때 사용됩니다. 이때 광고 패킷 안에는 Target Device Address(연결 대상 장치의 MAC 주소)가 포함되며, 따라서 이 MAC 주소가 일치하는 장치만 연결을 시도할 수 있습니다. Direct Advertising은 다시 두 가지 유형으로 나뉩니다.
HIGH Duty Direct Advertising은 매우 짧은 간격(약 3.75ms~10ms)으로 빠르게 광고하여,
가능한 한 빠른 재연결을 목표로 합니다. Fast Pairing이나 자동 재연결 기능을 구현할 때 사용되며,
사용자가 이어폰 케이스를 열자마자 폰과 즉시 연결되는 경험을 제공하기 위한 방식입니다.
다만 소비 전력이 크기 때문에 스펙상 최대 1.28초까지만 사용이 허용됩니다.
반면, LOW Duty Direct Advertising은 이러한 빠른 연결보다는 배터리 활용 효율을 우선합니다.
간격이 더 길고 전력 소모가 적으며 HIGH Duty 모드 실패 후 이어서 동작하는 경우가 일반적입니다.
즉 HIGH Duty로 빠르게 재연결을 시도하고, 실패하면 LOW Duty 모드로 전환하여
장시간 동안 연결 가능 상태를 유지하는 구조입니다.
정리하면 HIGH Duty는 '빠른 연결 우선', LOW Duty는 '배터리 효율과 지속성 우선'이라는 차이가 있습니다.

3. own_addr_type :BLE장치가 광고하거나 연결할때 어떤종류의 Bluetooth 주소 형식을 사용할지 정의하는 속성입니다.

typedef enum {

BLE_ADDR_TYPE_PUBLIC = 0x00, /*!< Public Device Address */

BLE_ADDR_TYPE_RANDOM = 0x01, /*!< Random Device Address. To set this address, use the function esp_ble_gap_set_rand_addr(esp_bd_addr_t rand_addr) */

BLE_ADDR_TYPE_RPA_PUBLIC = 0x02, /*!< Resolvable Private Address (RPA) with public identity address */

BLE_ADDR_TYPE_RPA_RANDOM = 0x03, /*!< Resolvable Private Address (RPA) with random identity address. To set this address, use the function esp_ble_gap_set_rand_addr(esp_bd_addr_t rand_addr) */

} esp_ble_addr_type_t;

4. channel_map : BLE 광고가 어떤 채널에서 송출될지 결정하는 속성입니다.
BLE 광고는 37,38,39광고에서 송출됩니다. 3개의 채널을 사용하는 이유는 스캔되고 발견될 확률증가, WI-FI 간섭 회피, 패킷손실감소 목적입니다. BLE장비 대부분 37,38,39모두를 사용합니다.

typedef enum {

ADV_CHNL_37 = 0x01,

ADV_CHNL_38 = 0x02,

ADV_CHNL_39 = 0x04,

ADV_CHNL_ALL = 0x07,

} esp_ble_adv_channel_t;

5. esp_ble_adv_filter_t : BLE 광고가 어떤 디바이스의 스캔/연결 요청을 허용할지 정하는 보안/동작 정책입니다.

typedef enum {

///Allow both scan and connection requests from anyone

ADV_FILTER_ALLOW_SCAN_ANY_CON_ANY = 0x00,

///Allow both scan req from White List devices only and connection req from anyone

ADV_FILTER_ALLOW_SCAN_WLST_CON_ANY,

///Allow both scan req from anyone and connection req from White List devices only

ADV_FILTER_ALLOW_SCAN_ANY_CON_WLST,

///Allow scan and connection requests from White List devices only

ADV_FILTER_ALLOW_SCAN_WLST_CON_WLST,

///Enumeration end value for advertising filter policy value check

} esp_ble_adv_filter_t;

결론적으로 이 프로젝트에서 광고방식은 광고를 20ms마다 하고, 누구나 스캔할 수 있지만 연결은 불가능한(Scannable Undirected) 방식으로 송출되며, 모든 광고 채널을 사용해 자신의 존재를 알리도록 설정되어 있습니다.

*adv_raw_data, scan_rsp_raw_data 변수
AD types의 기본 포맷은 length, AD Type, AD Data입니다.
AD types에 대해서는 이전 글에 설명이 있습니다.
https://wowon.tistory.com/373

//configure raw data for advertising packet

static uint8_t adv_raw_data[] = {

0x02, ESP_BLE_AD_TYPE_FLAG, 0x06,

0x11, ESP_BLE_AD_TYPE_NAME_CMPL, 'B', 'l', 'u', 'e', 'd', 'r', 'o', 'i', 'd', '_', 'B', 'e', 'a', 'c', 'o', 'n',

0x02, ESP_BLE_AD_TYPE_TX_PWR, 0x09,

0x03, ESP_BLE_AD_TYPE_APPEARANCE, 0x00,0x02,

0x02, ESP_BLE_AD_TYPE_LE_ROLE, 0x00,

};

static uint8_t scan_rsp_raw_data[] = {

0x08, ESP_BLE_AD_TYPE_LE_DEV_ADDR, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00,

0x11, ESP_BLE_AD_TYPE_URI, URI_PREFIX_HTTPS, '/', '/', 'e', 's', 'p', 'r', 'e', 's', 's', 'i', 'f', '.', 'c', 'o', 'm',

};

ADV_TYPE_SCAN_IND 타입이므로 스캔요청에 응답이 가능한 타입입니다.
그래서 앱을보면 BT 주소, URI이 나와있습니다. 스캔요청이 불가능한 ADV_TYPE_NONCONN_IND타입으로 바꿔서 확인해보겠습니다.

ADV_TYPE_NONCONN_IND 타입은 스캔 데이터가 없는 것을 확인할 수 있습니다.

다음글에서는 BLE가 광고되는 흐름에대해 알아보겠습니다.

BLE GATT를 Ble Sniffer로 측정하기

원원 — Sun, 16 Nov 2025 13:21:08 +0900

안녕하세요. 오늘은 이전에 알아봤던 BLE GATT를 BLE Sniffer로 측정해보겠습니다.
측정하는 방식과 알아보는 방식은 이전에 BLE GAP을 BLE Sniffer로 측정했던 방식과 동일합니다.

스마트폰 앱에서 CONNECT 버튼을 확인할 수 있습니다.

(1) ADV_IND
- CONNECT를 하기전에는 ESP32가 advertising 하고있습니다.

(2) CONNECT_IND
- 스마트폰에서 CONNECT를하면 연결시도를 합니다.
CONNECT_IND 패킷 안에 설정정보를 만듭니다. 이중에 Access Address가 있는데, 데이터 채널에서 사용되는 32bit 주소입니다. 이 주소로 LL/ATT/GATT 패킷이 전송됩니다. CONNECT_IND 이후부터는 데이터채널로 전환됩니다.

(3) Control Opcode: LL_VERSION_IND
- 연결시도 이후에 BLE 버전정보를 교환하게 됩니다.

(4) Empty PDU
- 연결을 유지하려고 스마트폰과 ESP32는 서로 패킷을 보냅니다.

(5) LL_FEATURE_REQ/LL_FEATURE_RSP
- 지원 기능(Encrption, DLE, PHY등) 동기화 과정입니다.

(6) LL_LENGTH_REQ/LL_LENGTH_RSP
- 데이터 길이 협상입니다.

(7) Sent Read By Group Type Request, Primary Service, Handles : 0x0001..0xffff (No.26662)
- 스마트폰이 ESP32의 GATT Primary Service(0x2800) 목옥을 요청하는 패킷입니다.

(8) Rcvd Read By Group Type Response, Attribute List Length: 3, GATT, GAP, Heart Rate (No.26669)
- ESP32가 Primary Service목록 3개 (GAP,GATT,Heart Rate)를 가지고있다고 답변한 패킷입니다.
마지막 Attribute Data의 Group End Handle을 보면 0x002b입니다. 그 의미는 Attribute Data가 더 있다는 말입니다.

(9) Sent Read By Group Type Request, Primary Service, Handles: 0x002c..0xffff(No. 26676)
- GATT Primary Service 목록을 다시 요청합니다. Group End Handle가 0x002b였으므로 0x002b+1부터 시작합니다.

(10) Rcvd Read By Group Type Response, Attribute List Length: 1, Automation IO (No.26679)
- 응답입니다. Group end Handle가 0xffff이므로 서비스의 끝을 의미합니다.

(11) 그 다음에는 각각의 UUID들의 Include Service와 Characteristic을 요청합니다.

여기까지 했으면 스마트폰에서는 아래의 UI들이 보입니다.

이 상태에서는 스마트폰과 ESP32는 Empty PDU 패킷을 교환하고있습니다.

[테스트]

Generic Access의 Device Name을 얻으면 ESP32가 읽힙니다.

(1) Sent Read Request, Handle: 0x0016 (GAP: Device Name)
- 스마트폰에서 Handle 0x0016을 Read Request합니다.

(2) Rcvd Read Response, Handle: 0x0016 (GAP: Device Name)
- ESP32가 Request에 대해서 응답을 합니다.

BLE GATT 예시를 통해서 알아보기

원원 — Mon, 10 Nov 2025 00:30:58 +0900

안녕하세요. 오늘은 BLE GATT에 대해 알아보겠습니다.

GATT(Generic Attribute Profile)는 BLE에서 장치 간 데이터를 교환하기 위해 '서비스'와 '특성'구조로 정의된 통신프로토콜입니다.

GATT가 실제로 어떻게 사용하는지 ESP32와 스마트폰앱(nRF Connect)를 이용해서 알아보겠습니다.
ESP32에 넣은 예제는 "Bluedroid_GATT_Server" 입니다.
https://github.com/espressif/esp-idf/tree/master/examples/bluetooth/ble_get_started/bluedroid/Bluedroid_GATT_Server

스마트폰 앱으로 연결해서 GATT 서비스를 확인한 사진입니다.

각 서비스는 UUID(Universally Unique Identifier)로 구분이 됩니다. UUID의 역할은 데이터가 무엇인지 구분하기 위함입니다.
UUID는 아래의 문서에 정의되어있습니다.
https://www.bluetooth.com/wp-content/uploads/Files/Specification/HTML/Assigned_Numbers/out/en/Assigned_Numbers.pdf

예시로, 앱에서 0x180D가 Heart Rate로 표시되어 있고, 문서에서도 동일하게 Heart Rate Service로 명시되어 있습니다.
UUID는 원래 128비트(16바이트) 이지만, 표준 UUID는 16비트로 축약하여 표현할 수 있습니다.
따라서 0x180D를 128비트 형식으로 확장하면, Bluetooth SIG에서 정의한 기본 포맷인
0000XXXX-0000-1000-8000-00805F9B34FB에 대입하여 최종적으로 0000180D-0000-1000-8000-00805F9B34FB가 됩니다.

사용자정의 UUID도 있습니다. Bluetooth SIG가 정해놓은 UUID외에 회사가 직접 만들어서 사용하는 128비트 UUID입니다. 해당 UUID는 정해진 포맷이 없습니다.

0x1801 UUID부터 알아보겠습니다.
BLE의 GATT구조(서비스/특성)를 관리하는 서비스입니다.
내부 데이터베이스가 바뀌면 Service Changed 특성으로 클라이언트에게 알립니다.
BLE 스택이 자동으로 추가하기때문에 FW에 명시적으로 넣지 않아도 거의 항상 존재합니다.

Service Changed는 GATT 구조 자체가 바뀔 때만 발생합니다.

여기서 나온 Service의 의미입니다.

Core_v5.0.pdf / 2229page

Profile : BLE의 최상위 개념입니다. 한 기기의 기능묶음 전체 입니다.
Service : 실제 기능 단위입니다. 하나의 profile안에 여러 서비스가 있을 수 있습니다.(예:0x180D,0x1815)
Include : 한 서비스 안에 다른 서비스를 참조해서 같이 쓰는 기 능입니다.
Characteristic : 데이터 정의(틀)입니다.
Properties : 값에 대해 가능한 동작입니다. (Read/Write/Notify/Indicate등)
Value : 실제 데이터타 값입니다.
Descriptor : 부가정보입니다. (설명, Notify설정, 포맷 등)

0x1800은 Generic Access이고 BLE 장치의 기본 정보를 나타내는 서비스입니다.
장치이름, apperance, 연결방식 등 광고.연결 단계에서 필요한 기본 데이터를 제공합니다.
BLE기기라면 거의 무조건 포함됩니다.

0x2A00: 장치이름
0x2A01 : 장치의 외형 타입입니다. 해당기기가 어떤 종류인지 나타내는 코드입니다.
(ex : 0: unknow, 64: phone, 128: computer .....)
0x2AA6 : BLE장치가 랜덤주소를 실주소로 변환(해석)할 수 있는지 여부를 나타냅니다.

0x180D, 0x1815는 Heart Rate와 Automation IO를 나타냅니다.
Heart Rate는 앱에서 심박수관련 정보를 Read할수있고, Automation IO는 앱에서 OFF/ON를 write 할 수 있습니다.

앱에서 특정 동작이 수행될 경우, BLE 장비 측에서 해당 이벤트 로그가 발생하도록 구성되어 있습니다.

BLE GAP을 BLE Sniffer로 측정하기

원원 — Sat, 8 Nov 2025 14:17:00 +0900

안녕하세요. 오늘은 이전에 알아봤던 BLE GAP를 BLE Sniffer로 측정해보겠습니다.
측정 할 장비는 이전글에서 사용했었던 ESP32 beacon 프로젝트입니다.
(https://wowon.tistory.com/373)
측정장비는 NRF52832 USB이고 wireshark를 사용합니다.

(A) 스마트폰 nRF 앱으로 측정한 데이터입니다.

(B) sniffer장비로 측정한 데이터입니다.
로그에서 찍히는 데이터는 크게 두 부분으로 나뉩니다.

- nRF Sniffer for Bluetooth LE
Sniffer 장비가 BLE 기기가 보낸 무선 신호(RF) 를 수신하고, 그 신호로부터 신호 세기(RSSI), 채널 번호, 타임스탬프 등의 물리 계층(PHY) 정보를 계산하여 Wireshark로 전달한 데이터

- Bluetooth Low Energy Link Layer
Sniffer 장비가 수신한 RF 신호를 Wireshark가 BLE 프로토콜 구조에 따라 해석한 데이터로, 패킷의 형식(ADV_IND, SCAN_REQ 등), 송신 주소(AdvA), UUID, 페이로드 내용 등 링크 계층(LL)의 논리적인 통신 정보를 나타냄

파랑색부분이 nRF Sniffer for Bluetooth LE이고 흰색부분이 Bluetooth Low Energy Link Layer입니다.

nRF Sniffer for Bluetooth LE에서 RSSI와 채널이 있는것을 확인할수있습니다.

Bluetooth Low Energy Link Layer은 자세히 알아보겠습니다. (ADV_SCAN_IND)

-Access Address(빨강네모)
계층 : PHY(물리계층)
역할 : 패킷의 시작을 식별하기 위한 고유 32비트 패턴입니다. 광고 채널 (37,38,39)에서는 항상 고정값 0x8e89bed6을 사용합니다. sniffer는 이 패턴을 보고 BLE 패킷이 시작인것을 인지합니다.

- Packey Header(주황네모)
계층 : Link Layer(논리 계층)
역할 : 패킷이 어떤 종류인지, 길이가 얼마나 되는지를 알려주는 메타데이터

필드	비트 수	설명
PDU Type	4bit	패킷 종류 (ADV_IND, ADV_SCAN_IND, CONNECT_REQ 등)
RFU	1bit	예약
TxAdd	1bit	송신 주소 형식 (0: Public, 1: Random)
RxAdd	1bit	수신 주소 형식
Length	8bit	Payload 길이 (0~37 byte)

- Advertising Address(노랑네모)
계층 : Link Layer
역할 : BLE 기기의 송신자 주소(MAC Adress 또는 랜덤 주소)입니다. 실제로 패킷을 보낸 BLE장치의 주소입니다. 이 값을 보고 누가 광고 패킷을 보냈는지 식별합니다.

- Advertising Data (초록네모)
계층 : GAP
역할 : 실제로 전달하려는 정보가 들어있는 영역입니다.
구조는 길이+타입+값 형태로 반복됩니다.

- CRC (파랑네모)
계층 : PHY(물리 계층)
역할 : 패킷에 오류가 생겼는지 확인하는 에러 검출 코드입니다.

* 앱 vs sniffer 데이터 비교

앱에서 봤던 데이터랑 sniffer의 Advertising Data를 보면 같고 코드에 적혀있는 데이터랑 매칭이 됩니다.(주황)
0x0201061109426C756564726F69645F426561636F6E020A0903190002021C00

static uint8_t adv_raw_data[] = {

0x02, 0x01, 0x06, // Flags

0x11, 0x09, 'B', 'l', 'u', 'e', 'd', 'r', 'o', 'i', 'd', '_', 'B', 'e', 'a', 'c', 'o', 'n', // Complete Local Name

0x02, 0x0A, 0x09, // TX Power Level = +9 dBm

0x03, 0x19, 0x00, 0x02, // Appearance = 0x0200

0x02, 0x1C, 0x00, // LE Role = Only Peripheral role supported

};

앱에서는 이 데이터가 있는데 sniffer에서는 이 데이터가 없습니다. (초록)
081BD2A4220CDADC001124172F2F6573707265737369662E636F6E

static uint8_t scan_rsp_raw_data[] = {

0x08, 0x1B, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00,

0x11, 0x24, 0x17, '/', '/', 'e', 's', 'p', 'r', 'e', 's', 's', 'i', 'f', '.', 'c', 'o', 'n',

};

※ 코드는 081B0000..인데 실제 데이터는 081BDA4..인 이유는 ESP32 FW에서 local_addr을 읽어서 넣기때문입니다.

ret = esp_ble_gap_get_local_used_addr(local_addr, &local_addr_type);

if (ret) {

ESP_LOGE(DEMO_TAG, "get local used address failed, error code = %x", ret);

return;

}

scan_rsp_raw_data[2] = local_addr[5];

scan_rsp_raw_data[3] = local_addr[4];

scan_rsp_raw_data[4] = local_addr[3];

scan_rsp_raw_data[5] = local_addr[2];

scan_rsp_raw_data[6] = local_addr[1];

scan_rsp_raw_data[7] = local_addr[0];

제가 봤던 sniffer 데이터는 ESP가 주기적으로 광고하는 ADV_SCAN_IND타입이기때문입니다.
scan_rsp데이터는 SCAN_RSP타입의 데이터를 봐야합니다.

타입은 Packet Header에 나와있습니다.

ADV_SCAN_IND

SCAN_REQ

SCAN_RSP

ADV_SCAN_IND는 ESP가 광고하는데이터이고, SCAN_REQ는 스캐너가 SCAN을 요청하는 데이터입니다. SCAN_RSP는 ESP가 SCAN에 응답하는 데이터입니다.

SCAN_RSQ 데이터입니다.

SCAN_RSP 데이터입니다.

빨강색부분이 Advertising Data이고 앱에있는 데이터랑 같습니다.

다음 글에서는 GAPP에 대해 알아보겠습니다.

BLE GAP 예시를 통해서 알아보기

원원 — Sun, 2 Nov 2025 23:05:43 +0900

안녕하세요. 오늘은 BLE GAP에 대해 알아보겠습니다.

GAP(Generic Access Profile)은 기기가 서로 어떻게 찾고 연결하는지 관리를 합니다.
GAP는 프로파일 계층에서 최상위에 존재합니다.

Core_v5.0.pdf / 1981page

GAP가 실제로 어떻게 사용하는지 ESP32와 스마트폰앱(nRF Connect)를 이용해서 알아보겠습니다.
ESP32에 넣은 예제는 "Bluedroid_Beacon" 입니다. 비콘으로 동작하는 펌웨어입니다.
FW : https://github.com/espressif/esp-idf/tree/master/examples/bluetooth/ble_get_started/bluedroid/Bluedroid_Beacon

OPEN 버튼을 클릭하면 해당사이트로 가집니다

스마트폰앱으로 보면 위의 그림처럼 나와있습니다.
- Device type : esp_bt_controller_mem_release결과와 Flags비트를 조합해서 표시
- Advertising type : 광고 PDU형식과 Controller PHY 설정으로 판단됨

앱에서 표시된 데이터들이 코드에서 어느부분이 매칭되는지 확인해보겠습니다.

표시 항목	값	설명
Device type	LE only	esp_bt_controller_mem_release(ESP_BT_MODE_CLASSIC_BT)
Advertising type	Legacy	esp_ble_gap_start_advertising(&adv_params);
Flags	LE General Discoverable, BR/EDR Not Supported	ESP_BLE_AD_TYPE_FLAG (0x01) = 0x06
Complete Local Name	Bluedroid_Beacon	ESP_BLE_AD_TYPE_NAME_CMPL (0x09)
Tx Power Level	9 dBm	ESP_BLE_AD_TYPE_TX_PWR (0x0A) = 0x09
Appearance	[512] Generic Tag	ESP_BLE_AD_TYPE_APPEARANCE (0x19) = 0x0200
LE Role	Only Peripheral Role supported	ESP_BLE_AD_TYPE_LE_ROLE (0x1C) = 0x00
BLE Address	DC:DA:0C:22:A4:D2	esp_ble_gap_get_local_used_addr() 에서 가져옴
URI	https://espressif.com	ESP_BLE_AD_TYPE_URI (0x24) = URI_PREFIX_HTTPS (0x17) + "//espressif.com"

가장 직관적인 Tx Power Level을 보겠습니다. 값은 9입니다.

//configure raw data for advertising packet

static uint8_t adv_raw_data[] = {

0x02, ESP_BLE_AD_TYPE_FLAG, 0x06,

0x11, ESP_BLE_AD_TYPE_NAME_CMPL, 'B', 'l', 'u', 'e', 'd', 'r', 'o', 'i', 'd', '_', 'B', 'e', 'a', 'c', 'o', 'n',

0x02, ESP_BLE_AD_TYPE_TX_PWR, 0x09,

0x03, ESP_BLE_AD_TYPE_APPEARANCE, 0x00,0x02,

0x02, ESP_BLE_AD_TYPE_LE_ROLE, 0x00,

};

static uint8_t scan_rsp_raw_data[] = {

0x08, ESP_BLE_AD_TYPE_LE_DEV_ADDR, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00, 0x00,

0x11, ESP_BLE_AD_TYPE_URI, URI_PREFIX_HTTPS, '/', '/', 'e', 's', 'p', 'r', 'e', 's', 's', 'i', 'f', '.', 'c', 'o', 'm',

};

AD types의 기본 포맷은 아래의 그림과 같습니다.
length, AD Type, AD Data입니다.

Core_v5.0.pdf / 2086page

TX Power Level을 보면 아래와 같고 길이가 0x02이고 AD Type은 ESP_BLE_AD_TYPE_TX_PWR이고 데이터는 0x09입니다.
0x02, ESP_BLE_AD_TYPE_TX_PWR, 0x09,
ESP_BLE_AD_TYPE_TX_PWR은 0x0A입니다.
ESP_BLE_AD_TYPE_TX_PWR = 0x0A,
AD Type은 아래의 문서에 정의되어있습니다.
https://www.bluetooth.com/wp-content/uploads/Files/Specification/HTML/Assigned_Numbers/out/en/Assigned_Numbers.pdf

다른 GAP 데이터들도 찾아보면 해당문서에 나와있것과 일치합니다.

////

BLE 이므로 광고를 계속하는데 아래의 데이터로 설정합니다.
20ms 주기로 광고를 합니다.

static esp_ble_adv_params_t adv_params = {

.adv_int_min = 0x20, // 20ms

.adv_int_max = 0x20, // 20ms

.adv_type = ADV_TYPE_SCAN_IND,

.own_addr_type = BLE_ADDR_TYPE_PUBLIC,

.channel_map = ADV_CHNL_ALL,

.adv_filter_policy = ADV_FILTER_ALLOW_SCAN_ANY_CON_ANY,

};

해당데이터도 문서에 정의되어있습니다. 해당 adv type 설명은 아래의 링크에 나와있습니다.
https://wowon.tistory.com/377

Core_v5.0.pdf 1251 page

다음글에서는 GAP를 Sniffer로 측정해보겠습니다.

ESP32 Command Line 개발환경

원원 — Sun, 26 Oct 2025 20:08:31 +0900

안녕하세요. ESP32 커맨드라인 컴파일을 해보겠습니다.

1. 아래의 사이트에 들어가서 컴파일에 필요한 파일을 다운로드받습니다.
https://dl.espressif.com/dl/esp-idf/?idf=4.4

2. 설치된 커맨드 프로그램을 킵니다.

3. SDK에 들어가서 example을 다른곳으로 옮깁니다. (다운받은경로\frameworks\esp-idf-v5.2.6\examples\get-started\hello_world)

4. 프로젝트의 경로에가서 아래의 커맨드를 하나씩 입력합니다.
1. 타겟보드 설정 : idf.py set-target "target"
"target"에 자신의 ESP32정보를 넣습니다.
        esp32,
        esp32s2,
        esp32c3,
        esp32s3,
        esp32c2,
        esp32c6,
        esp32h2,
        linux,
        esp32p4
2. 옵션설정 : idf.py menuconfig
3. 빌드 : idf.py build
4. 플래시: idf.py –p "COM PORT" flash
"COM PORT"에 연결된 comport 정보를 넣습니다. (예시 : COM12 => idf.py -p com12 flash)
idf.py flash를 하면 자동으로 comport를 찾아서 fw를 넣어줍니다.
5. 모니터 : Idf.py –p "COM PORT" monitor
"COM PORT"에 연결된 comport 정보를 넣습니다. (예시 : COM12 => idf.py -p com12 flash)
6. 플래시 + 빌드 동시에하기 : idf.py build flash

5. monitor를하면 커맨드프로그램에서 로그를 볼 수 있습니다.

ESP32 vscode개발환경 만들기(ESP-IDF)

원원 — Sun, 26 Oct 2025 15:34:07 +0900

안녕하세요. 오늘은 ESP32 vscode로 개발환경을 만들어보겠습니다.

1. vscode를 설치합니다.
https://code.visualstudio.com/download

2. EXTENSIONS에서 ESP-IDF를 설치합니다.

3.좌측에 ESP-IDF 아이콘을 클릭 후 Configure ESP-IDF Extension을 클릭하고 ADVANCE를 클릭합니다.

4. ESP-IDF container directory는 SDK이고 ESP-IDF Tools directory는 개발도구입니다. 경로를 정하고 Configure Tools를 클릭합니다.

5. 그 다음 또 툴을 설치하는게 나오는데 Donwload Tools를 클릭합니다.

6.설치가 완료되면 이제 예제를 불러와봅니다. ESP-IDF:Show Example Projects를 클릭합니다.

7.hello_world를 클릭하고 Select location for creating hellow_world project를 클릭합니다.
사실 이 예제는 아까 설치했던 SDK에서 불러오는것입니다.
(v5.5\esp-idf\examples\get-started\hello_world\main)

8. 아래의 아이콘에서 COM포트와 사용중인 MCU를 클릭합니다.
스패너 버튼은 build버튼이고, 번개 버튼은 flash 버튼입니다.

9. UART를 연결해서 보면 Hello world! 로그가 찍힙니다.